An HLASM started task that reads CICS SMF type 110 subtype 1 records straight from an SMF in-memory resource and sends them over TCP to a collector written in Go, without waiting for the SMF dump.
Each name links to the matching line in the source below.
----+----1----+----2----+----3----+----4----+----5----+----6----+----7--
TITLE 'SMFREAL - CICS SMF 110-1 REAL TIME FORWARDER (HLASM)'
*---------------------------------------------------------------------
* SMFREAL 2.0 - HLASM VERSION OF THE SMFREAL STARTED TASK
*
* READS CICS SMF 110 SUBTYPE 1 RECORDS FROM AN SMF IN-MEMORY RESOURCE
* (IFAMCON/IFAMGET/IFAMDSC, AMODE 64 SERVICES) AND FORWARDS THEM OVER
* TCP TO THE SMFREAL COLLECTOR (GO). SAME WIRE PROTOCOL, CONFIGURATION
* (DD SMFRCFG), MESSAGES AND OPERATOR COMMANDS AS THE C VERSION 1.3.
*
* TASKS (ONE OBJECT, THREE LOAD MODULES - SEE CBT.SMFREAL.JCL(BUILD))
* SMFREAL MAIN: CONFIG, SINGLE INSTANCE LOCK, RING, ATTACHES THE
* SUBTASKS, OPERATOR COMMANDS (EXTRACT/QEDIT):
* F SMFREAL,STATUS | TRACE ON | TRACE OFF (APPL= OK)
* P SMFREAL
* SMFRGET GETTER: IFAMCON + BLOCKING IFAMGET STRAIGHT INTO THE NEXT
* FREE 32K SLOT OF THE RING, COMMITS ONLY 110-1 RECORDS AND
* CACHES THE LAST DICTIONARY (CLASS 1) OF EVERY APPLID.
* SMFRSND SENDER: TCP CLIENT (Z/OS UNIX CALLABLE SERVICES). HELLO,
* DICTIONARY REPLAY, BATCHES OF RECORDS IN ONE WRITEV,
* CUMULATIVE ACKS, HEARTBEAT AND STATUS FRAMES. A SLOT IS
* FREED ONLY WHEN THE COLLECTOR ACKS IT (DB COMMIT).
*
* ATTRIBUTES: AMODE 31, RMODE 24, NOT REENTRANT (EVERY TASK RUNS ITS
* OWN COPY OF THE MODULE; SHARED STATE LIVES IN THE ANCHOR, R9).
* THE IFAM SERVICES ARE CALLED IN AMODE 64 (SAM64) WITH A F4SA.
*
* REGISTERS: R12,R11,R10,R7,R6 BASES R9 ANCHOR R13 SAVE AREA
* INTERNAL ROUTINES: JAS R14,RTN / BAKR R14,0 ... PR (R2-R14 KEPT,
* RESULTS IN R15 AND R0).
*---------------------------------------------------------------------
*
*--------------------------------------------------------- MACROS ---
MACRO
&L ENT$
&L STM R14,R12,12(R13)
LARL R12,SMFREAL
LAY R11,4096(,R12)
LAY R10,4096(,R11)
LAY R7,4096(,R10)
LAY R6,4096(,R7)
ST R13,SAVEA+4
LA R13,SAVEA
MEND
*
MACRO
&L MSG$
&L XC MSGLEN,MSGLEN
MEND
*
MACRO
&L TXT$ &S
LCLC &A
&A SETC 'T&SYSNDX'
&L LARL R1,&A
LHI R0,L'&A
JAS R14,APPTXT
TEXT LOCTR
DS 0H
&A DC C&S
SMFREAL LOCTR
MEND
*
MACRO
&L FLD$ &A,&N
&L LA R1,&A
LHI R0,&N
JAS R14,APPFLD
MEND
*
MACRO
&L FLDH$ &A,&H
&L LA R1,&A
LH R0,&H
JAS R14,APPFLD
MEND
*
MACRO
&L DEC$ &A
&L LA R1,&A
JAS R14,APPDEC
MEND
*
MACRO
&L DECF$ &A
&L LA R1,&A
JAS R14,APPDECF
MEND
*
MACRO
&L DECR$ &R
&L STG &R,DECTMP
LA R1,DECTMP
JAS R14,APPDEC
MEND
*
MACRO
&L HEX$ &A,&N
&L LA R1,&A
LHI R0,&N
JAS R14,APPHEX
MEND
*
MACRO
&L OUT$ &W
&L LHI R0,&W
JAS R14,LOGOUT
MEND
*
MACRO
&L NOW$ &R
&L STCK TODW
LG &R,TODW
SRLG &R,&R,12
MEND
*
MACRO
&L INC$ &F
&L LG R0,&F
AGHI R0,1
STG R0,&F
MEND
*
MACRO
&L CLOSE$ &S
LCLC &A
&A SETC 'C&SYSNDX'
&L LARL R1,&A
LHI R0,L'&A
JAS R14,CLOSEC
TEXT LOCTR
DS 0H
&A DC C&S
SMFREAL LOCTR
MEND
*
*--------------------------------------------------------- EQUATES --
SLOTSZ EQU 32800 SLOT: LEN(4) HDR(20) DATA(32768)+8
SLDATA EQU 24 OFFSET OF THE SMF RECORD IN A SLOT
MAXREC EQU 32768 LARGEST SMF RECORD
MAXDICT EQU 64 CACHED DICTIONARIES
IOVMAX EQU 120 BPXYIOV IOV_MAX
MSGMAX EQU 700 MESSAGE / FRAME TEXT BUFFER
RBUFSZ EQU 1280 ACK RECEIVE BUFFER
EINTR EQU 120
PT#HELLO EQU 1
PT#REC EQU 2
PT#DICT EQU 3
PT#HB EQU 4
PT#STAT EQU 5
PT#ACK EQU X'81'
*
SMFREAL CSECT
SMFREAL AMODE 31
SMFREAL RMODE 24
SYSSTATE ARCHLVL=2
DATA LOCTR
TEXT LOCTR
BUF LOCTR
SMFREAL LOCTR
YREGS
USING SMFREAL,R12,R11,R10,R7,R6
USING ANC,R9
ENTRY SMFRGET,SMFRSND
J MAIN
DC C'SMFREAL 2.0 HLASM &SYSDATE &SYSTIME '
*
***********************************************************************
* MAIN TASK *
***********************************************************************
MAIN ENT$
MVC RETC,=F'0'
STORAGE OBTAIN,LENGTH=ANCLEN,LOC=31
LR R9,R1
ST R9,ANCP
LR R2,R9
LHI R3,ANCLEN
SLR R4,R4
SLR R5,R5
MVCL R2,R4 CLEAR THE ANCHOR
MVC ALOCKFD,=F'-1'
MVC AWAKER,=F'-1'
MVC AWAKEW,=F'-1'
OPEN (PRTDCB,OUTPUT),MODE=31
TM PRTDCB+(DCBOFLGS-IHADCB),DCBOFOPN
JNO MA010
LA R1,PRTDCB
ST R1,APRTDCB
MA010 JAS R14,IDENT
MSG$
TXT$ 'SMFR001I SMFREAL 2.0 STARTING ON '
FLD$ ASYSN,8
TXT$ ' JOB '
FLD$ AJOBN,8
TXT$ ' '
FLD$ AJOBID,8
OUT$ 1
MSG$
TXT$ 'SMFR001I MODIFY: F '
FLD$ AJOBN,8
TXT$ ',STATUS | TRACE ON | TRACE OFF (APPL= OPTIONAL)'
OUT$ 0
JAS R14,CFGDFLT
JAS R14,CFGREAD
JAS R14,CFGFIX
JAS R14,SHOWCFG
ICM R0,15,CFGBAD
JZ MA020
MSG$
TXT$ 'SMFR004E '
DECF$ CFGBAD
TXT$ ' CONFIG ERRORS, CHECK SMFRCFG'
OUT$ 1
MA020 JAS R14,SINGLE
LTR R15,R15
JZ MA030
MVC RETC,=F'8'
J MAEXIT
* RING, DICTIONARIES, PIPE
MA030 L R0,ASLOTS
MSFI R0,SLOTSZ
STORAGE OBTAIN,LENGTH=(R0),LOC=31,COND=YES
LTR R15,R15
JZ MA040
MSG$
TXT$ 'SMFR008E CANNOT ALLOCATE '
DECF$ ASLOTS
TXT$ ' SLOTS, CHECK REGION/MEMLIMIT'
OUT$ 1
MVC RETC,=F'12'
J MAEXIT
MA040 ST R1,ARING
L R0,=A(MAXDICT*MAXREC)
STORAGE OBTAIN,LENGTH=(R0),LOC=31,COND=YES
LTR R15,R15
JNZ MA041
ST R1,ADICTA
LA R2,ADICT
LHI R3,MAXDICT
MA042 ST R1,12(,R2) DATA POINTER OF EACH ENTRY
AL R1,=A(MAXREC)
LA R2,16(,R2)
JCT R3,MA042
CALL BPX1PIP,(AWAKER,AWAKEW,RV,RC,RSN),VL,MF=(E,CALLPL)
L R0,RV
LTR R0,R0
JNM MA050
MA041 MSG$
TXT$ 'SMFR008E STORAGE OR PIPE FAILED ERRNO='
DECF$ RC
OUT$ 1
MVC RETC,=F'12'
J MAEXIT
* OPERATOR COMMAND INTERFACE
MA050 EXTRACT ANSWER,FIELDS=COMM
L R8,ANSWER
USING COM,R8
QEDIT ORIGIN=COMCIBPT,CIBCTR=1
ICM R2,15,COMCIBPT START CIB ?
JZ MA060
QEDIT ORIGIN=COMCIBPT,BLOCK=(R2)
* SUBTASKS
MA060 LA R2,ASNDECB
ATTACH EP=SMFRSND,ECB=(R2),PARAM=(ANCP),VL=1
ST R1,ASNDTCB
LTR R15,R15
JNZ MA061
LA R2,AGETECB
ATTACH EP=SMFRGET,ECB=(R2),PARAM=(ANCP),VL=1
ST R1,AGETTCB
LTR R15,R15
JZ MA070
MA061 ST R15,WORKF
MSG$
TXT$ 'SMFR008E ATTACH FAILED RC='
DECF$ WORKF
OUT$ 1
MVC RETC,=F'12'
J MASTOP
MA070 MSG$
TXT$ 'SMFR005I '
FLD$ AJOBN,8
TXT$ ' READY FOR COMMANDS'
OUT$ 1
* COMMAND LOOP
MALOOP L R2,COMECBPT
ST R2,ECBL
LA R2,ASTOPECB
ST R2,ECBL+4
LA R2,AGETECB
ST R2,ECBL+8
LA R2,ASNDECB
O R2,=X'80000000'
ST R2,ECBL+12
WAIT 1,ECBLIST=ECBL
TM ASTOPECB,X'40' MAXRECS REACHED
JO MASTOP
TM AGETECB,X'40'
JO MADIED
TM ASNDECB,X'40'
JO MADIED
MACIB ICM R5,15,COMCIBPT
JZ MALOOP
USING CIB,R5
CLI CIBVERB,CIBSTOP
JNE MACIB2
MSG$
TXT$ 'SMFR042I STOP COMMAND ACCEPTED'
OUT$ 1
QEDIT ORIGIN=COMCIBPT,BLOCK=(R5)
J MASTOP
MACIB2 CLI CIBVERB,CIBMODFY
JNE MACIB3
JAS R14,DOMOD R15=1: STOP REQUESTED
LTR R15,R15
JZ MACIB3
QEDIT ORIGIN=COMCIBPT,BLOCK=(R5)
J MASTOP
MACIB3 QEDIT ORIGIN=COMCIBPT,BLOCK=(R5)
J MACIB
DROP R5
MADIED MSG$
TXT$ 'SMFR044E A SUBTASK ENDED UNEXPECTEDLY: GETTER='
HEX$ AGETECB,4
TXT$ ' SENDER='
HEX$ ASNDECB,4
OUT$ 1
MVC RETC,=F'12'
* SHUTDOWN
MASTOP MSG$
TXT$ 'SMFR043I SMFREAL STOPPING, DRAIN UP TO '
DECF$ ADRAIN
TXT$ 'S'
OUT$ 1
MVI ASTOP,1
JAS R14,WAKEUP
JAS R14,BREAKGET
ICM R2,15,AGETTCB
JZ MAST10
WAIT ECB=AGETECB
DETACH AGETTCB
MAST10 ICM R2,15,ASNDTCB
JZ MAST20
WAIT ECB=ASNDECB
DETACH ASNDTCB
MAST20 LHI R1,1
JAS R14,SHOWSTAT
MAEXIT MSG$
TXT$ 'SMFR099I SMFREAL ENDED RC='
DECF$ RETC
OUT$ 1
L R0,ALOCKFD
LTR R0,R0
JM MAEX10
CALL BPX1CLO,(ALOCKFD,RV,RC,RSN),VL,MF=(E,CALLPL)
MAEX10 ICM R0,15,APRTDCB
JZ MAEX20
CLOSE (PRTDCB),MODE=31
MAEX20 L R13,SAVEA+4
L R15,RETC
L R14,12(,R13)
LM R0,R12,20(R13)
BR R14
DROP R8
*
*---------------------------------------------------------------------
* IDENT - SYSNAME, JOBNAME, JOBID, START TIME, INSTANCE
*---------------------------------------------------------------------
IDENT BAKR R14,0
L R2,16(,0) CVT
MVC ASYSN,X'154'(R2) CVTSNAME
L R2,X'21C'(,0) PSATOLD -> TCB
L R3,X'0C'(,R2) TCBTIO
MVC AJOBN,0(R3) TIOCNJOB
MVC AJOBID,=CL8' '
L R3,X'B4'(,R2) TCBJSCB
N R3,=X'00FFFFFF'
JZ ID010
ICM R3,15,X'13C'(R3) JSCBSSIB
JZ ID010
MVC AJOBID,X'0C'(R3) SSIBJBID
ID010 STCK AINST
NOW$ R2
STG R2,ASTARTUS
LA R1,ASTARTT
JAS R14,FMTTS
MVI ASTARTT+10,C'T'
PR
*
*---------------------------------------------------------------------
* DOMOD - MODIFY COMMAND IN THE CIB (R5). R15=1 TO STOP
*---------------------------------------------------------------------
DOMOD BAKR R14,0
USING CIB,R5
MVC CMDW,BLANKS
LH R2,CIBDATLN
LTR R2,R2
JNP DM010
CHI R2,64
JNH *+8
LHI R2,64
AHI R2,-1
EX R2,DMMVC
DM010 OC CMDW,BLANKS UPPER CASE
CLC CMDW(5),=C'APPL='
JNE DM020
MVC CMDW(59),CMDW+5
MVC CMDW+59(5),BLANKS
DM020 CLI CMDW,C' ' LEADING BLANKS
JNE DM030
CLC CMDW,BLANKS
JE DM030
MVC CMDW(63),CMDW+1
MVI CMDW+63,C' '
J DM020
DM030 CLC CMDW(16),=CL16'STATUS'
JE DMSTAT
CLC CMDW(16),=CL16'STATS'
JE DMSTAT
CLC CMDW(16),=CL16'D'
JE DMSTAT
CLC CMDW(16),=CL16'TRACE ON'
JE DMTON
CLC CMDW(16),=CL16'TRACE=Y'
JE DMTON
CLC CMDW(16),=CL16'TRACE OFF'
JE DMTOFF
CLC CMDW(16),=CL16'TRACE=N'
JE DMTOFF
CLC CMDW(16),=CL16'STOP'
JE DMSTOP
CLC CMDW(16),=CL16'SHUTDOWN'
JE DMSTOP
MSG$
TXT$ 'SMFR041E UNKNOWN COMMAND '''
FLD$ CMDW,64
TXT$ '''. USE F '
FLD$ AJOBN,8
TXT$ ',STATUS | TRACE ON | TRACE OFF OR P '
FLD$ AJOBN,8
OUT$ 1
J DMRET0
DMSTAT LHI R1,1
JAS R14,SHOWSTAT
J DMRET0
DMTON MVI ATRACE,1
MSG$
TXT$ 'SMFR040I TRACE IS ON'
OUT$ 1
J DMRET0
DMTOFF MVI ATRACE,0
MSG$
TXT$ 'SMFR040I TRACE IS OFF'
OUT$ 1
J DMRET0
DMSTOP LHI R15,1
PR
DMRET0 LHI R15,0
PR
DMMVC MVC CMDW(0),CIBDATA
DROP R5
*
*---------------------------------------------------------------------
* BREAKGET - IFAMDSC FROM THE MAIN TASK: WAKES A BLOCKED IFAMGET
*---------------------------------------------------------------------
BREAKGET BAKR R14,0
CLI ASMFCON,0
JE BG010
XC DSPB,DSPB
MVC DSPB(4),=C'DSPB'
MVC DSPB+4(2),=H'24'
MVI DSPB+7,1
MVC DSPB+8(16),ATOKEN
L R15,=V(IFAMDSC)
LA R1,PLDSC
JAS R14,IFACALL
MSG$
TXT$ 'SMFR019I STOP DISCONNECT RC='
HEX$ IRC+3,1
TXT$ ' RSN='
HEX$ IRSN+2,2
OUT$ 0
BG010 PR
*
*---------------------------------------------------------------------
* SINGLE - ONE SMFREAL PER RESOURCE: FCNTL LOCK ON THE LOCK FILE.
* R15 = 0 OK, 8 ANOTHER INSTANCE / ERROR
*---------------------------------------------------------------------
SINGLE BAKR R14,0
CLC ALOCKL,=H'4'
JNE SI010
CLC ALOCK(4),=C'NONE'
JNE SI010
MSG$
TXT$ 'SMFR009W LOCKFILE=NONE: SINGLE INSTANCE CHECK OFF'
OUT$ 1
J SIOK
SI010 LH R0,ALOCKL
ST R0,WORKF
CALL BPX1OPN,(WORKF,ALOCK,FOPNOPT,FMODE,RV,RC,RSN),VL,MF=(E, X
CALLPL)
L R0,RV
LTR R0,R0
JNM SI020
MSG$
TXT$ 'SMFR009E CANNOT OPEN LOCK FILE '
FLDH$ ALOCK,ALOCKL
TXT$ ' ERRNO='
DECF$ RC
OUT$ 1
J SIBAD
SI020 ST R0,ALOCKFD
CALL BPX1FCM,(ALOCKFD,FMODE,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
XC BRLK,BRLK
MVC BRLK(2),=H'2' F_WRLCK, WHENCE 0, START 0, LEN 0
CALL BPX1FCT,(ALOCKFD,FSETLK,BRLKPTR,RV,RC,RSN),VL,MF=(E, X
CALLPL)
L R0,RV
LTR R0,R0
JNM SI050
* ALREADY LOCKED
LARL R2,HOLDBUF
MVC 0(255,R2),BLANKS
ST R2,BUFPTRW
CALL BPX1LSK,(ALOCKFD,DZERO,FZERO,RVD,RC2,RSN2),VL,MF=(E, X
CALLPL)
CALL BPX1RED,(ALOCKFD,BUFPTRW,FZERO,F255,RV2,RC2,RSN2),VL, X
MF=(E,CALLPL)
LHI R3,0
L R4,RV2
LTR R4,R4
JNP SI040
LR R1,R2 CUT AT THE NEWLINE (X'15')
SI030 CLI 0(R1),X'15'
JE SI040
LA R1,1(,R1)
AHI R3,1
JCT R4,SI030
SI040 STH R3,HOLDLEN
XC BRLK,BRLK
MVC BRLK(2),=H'2'
CALL BPX1FCT,(ALOCKFD,FGETLK,BRLKPTR,RV2,RC2,RSN2),VL,MF=(E, X
CALLPL)
MSG$
TXT$ 'SMFR009E '
FLDH$ ARES,ARESL
TXT$ ' IS ALREADY READ BY ANOTHER SMFREAL (PID '
DECF$ BRLK+20
TXT$ ') - THIS ONE ENDS'
OUT$ 1
LH R0,HOLDLEN
LTR R0,R0
JZ SI045
MSG$
TXT$ 'SMFR009E ACTIVE: '
LARL R1,HOLDBUF
LH R0,HOLDLEN
JAS R14,APPFLD
OUT$ 1
SI045 CALL BPX1CLO,(ALOCKFD,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
MVC ALOCKFD,=F'-1'
J SIBAD
* LOCKED: WRITE WHO WE ARE
SI050 CALL BPX1GPI,(WORKF),VL,MF=(E,CALLPL)
MSG$
TXT$ 'JOB '
FLD$ AJOBN,8
TXT$ ' '
FLD$ AJOBID,8
TXT$ ' PID '
DECF$ WORKF
TXT$ ' SYSTEM '
FLD$ ASYSN,8
TXT$ ' SINCE '
LA R1,TSWORK
JAS R14,FMTTS
LA R1,TSWORK
LHI R0,19
JAS R14,APPTXT
LA R1,NLCHAR
LHI R0,1
JAS R14,APPTXT
CALL BPX1FTR,(ALOCKFD,DZERO,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
CALL BPX1LSK,(ALOCKFD,DZERO,FZERO,RVD,RC2,RSN2),VL,MF=(E, X
CALLPL)
LARL R2,MSGBUF
ST R2,BUFPTRW
CALL BPX1WRT,(ALOCKFD,BUFPTRW,FZERO,MSGLEN,RV2,RC2,RSN2),VL, X
MF=(E,CALLPL)
MSG$
TXT$ 'SMFR009I SINGLE INSTANCE LOCK '
FLDH$ ALOCK,ALOCKL
TXT$ ' ACQUIRED'
OUT$ 0
SIOK LHI R15,0
PR
SIBAD LHI R15,8
PR
*
*---------------------------------------------------------------------
* CFGDFLT - DEFAULT CONFIGURATION
*---------------------------------------------------------------------
CFGDFLT BAKR R14,0
MVC ARESL,=H'14'
MVC ARES,=CL26'IFASMF.CICS110'
MVC AHOSTL,=H'9'
MVC AHOST(9),=C'127.0.0.1'
MVC APORT,=F'6110'
MVC ASLOTS,=F'2048'
MVC AWINDOW,=F'256'
MVC ABATCH,=F'64'
MVC ARETRY,=F'10'
MVC AHBEAT,=F'30'
MVC AACKTO,=F'60'
MVC ADRAIN,=F'15'
MVC ASTATINT,=F'15'
MVC ASTATSND,=F'30'
MVI ATRACE,0
XC AMAXREC,AMAXREC
XC ALOCKL,ALOCKL
XC CFGBAD,CFGBAD
PR
*
*---------------------------------------------------------------------
* CFGREAD - READ DD SMFRCFG (KEY=VALUE, COLUMNS 1-72)
*---------------------------------------------------------------------
CFGREAD BAKR R14,0
OPEN (CFGDCB,INPUT),MODE=31
TM CFGDCB+(DCBOFLGS-IHADCB),DCBOFOPN
JO CR010
MSG$
TXT$ 'SMFR003W CONFIG DD SMFRCFG NOT AVAILABLE, '
TXT$ 'USING DEFAULTS'
OUT$ 1
PR
CR010 LARL R8,CFGREC
MVC 0(80,R8),BLANKS
GET CFGDCB,(R8)
JAS R14,CFGLINE
J CR010
CFGEOF CLOSE (CFGDCB),MODE=31
PR
*
*---------------------------------------------------------------------
* CFGLINE - ONE CONFIG RECORD (R8)
*---------------------------------------------------------------------
CFGLINE BAKR R14,0
MVC LINE,0(R8)
LA R2,LINE FIRST NON BLANK
LHI R3,72
CL010 CLI 0(R2),C' '
JNE CL020
LA R2,1(,R2)
JCT R3,CL010
PR EMPTY LINE
CL020 CLI 0(R2),C'*'
JE CLRET
CLC 0(2,R2),=C'/*'
JE CLRET
LA R8,LINE+71 LAST NON BLANK
CL030 CLI 0(R8),C' '
JNE CL040
BCTR R8,0
J CL030
CL040 LA R8,1(,R8) R8 = END OF TEXT
LR R1,R2 FIND '='
CL050 CR R1,R8
JNL CLNOEQ
CLI 0(R1),C'='
JE CL060
LA R1,1(,R1)
J CL050
CL060 LR R3,R1 KEY = R2 .. R3 (TRIMMED)
CL065 CR R3,R2
JNH CL070
LR R4,R3
BCTR R4,0
CLI 0(R4),C' '
JNE CL070
LR R3,R4
J CL065
CL070 SR R3,R2 R3 = KEY LENGTH
LA R4,1(,R1) VALUE START
CL075 CR R4,R8
JNL CL080
CLI 0(R4),C' '
JNE CL080
LA R4,1(,R4)
J CL075
CL080 LR R5,R8
SR R5,R4 R5 = VALUE LENGTH (>=0)
MVC KEYW,BLANKS
LTR R3,R3
JNP CLBADK
CHI R3,16
JH CLBADK
LR R1,R3
BCTR R1,0
EX R1,CLMVKEY
OC KEYW,BLANKS UPPER CASE
JAS R14,CFGSET
CLRET PR
CLNOEQ MSG$
TXT$ 'SMFR004E CONFIG LINE IGNORED: '
LR R1,R2
LR R0,R8
SR R0,R2
JAS R14,APPTXT
OUT$ 1
J CLERR
CLBADK MSG$
TXT$ 'SMFR004E INVALID CONFIG KEY'
OUT$ 1
CLERR L R0,CFGBAD
AHI R0,1
ST R0,CFGBAD
PR
CLMVKEY MVC KEYW(0),0(R2)
*
*---------------------------------------------------------------------
* CFGSET - KEYW = KEY, R4/R5 = VALUE ADDRESS/LENGTH
*---------------------------------------------------------------------
CFGSET BAKR R14,0
LA R2,CFGTAB
CS010 CLI 0(R2),0
JE CSUNK
CLC KEYW(10),1(R2)
JNE CS015
CLC KEYW+10(6),BLANKS
JE CS020
CS015 LA R2,CFGTABL(,R2)
J CS010
CS020 LH R3,12(,R2) OFFSET IN THE ANCHOR
AR R3,R9
CLI 11(R2),C'S'
JE CSSTR
CLI 11(R2),C'Y'
JE CSFLAG
LR R1,R4
LR R0,R5
JAS R14,NUMPARSE R15 = VALUE, R0 = RC
LTR R0,R0
JNZ CSBADN
CLI 11(R2),C'D'
JE CSDBL
CLGFI R15,X'7FFFFFFF'
JH CSBADN
ST R15,0(,R3)
PR
CSDBL STG R15,0(,R3)
PR
CSFLAG MVI 0(R3),0
LTR R5,R5
JNP CSRET
CLI 0(R4),C'Y'
JE CSFY
CLI 0(R4),C'y'
JNE CSRET
CSFY MVI 0(R3),1
CSRET PR
CSSTR LH R1,14(,R2) MAX LENGTH
CR R5,R1
JNH *+6
LR R5,R1
STH R5,0(,R3)
LA R0,2(,R3) TARGET
LR R14,R4 SOURCE
LR R15,R5
LR R1,R5
MVCL R0,R14
PR
CSBADN MSG$
TXT$ 'SMFR004E INVALID NUMBER FOR '
FLD$ KEYW,16
OUT$ 1
J CSERR
CSUNK MSG$
TXT$ 'SMFR004E UNKNOWN CONFIG KEY '
FLD$ KEYW,16
OUT$ 1
CSERR L R0,CFGBAD
AHI R0,1
ST R0,CFGBAD
PR
*
*---------------------------------------------------------------------
* CFGFIX - LIMITS, HOST ADDRESS, DEFAULT LOCK FILE
*---------------------------------------------------------------------
CFGFIX BAKR R14,0
L R2,ASLOTS
CHI R2,16
JNL *+8
LHI R2,16
C R2,=F'32768'
JNH *+8
L R2,=F'32768'
ST R2,ASLOTS
L R3,AWINDOW
CHI R3,1
JNL *+8
LHI R3,1
CR R3,R2
JNH *+6
LR R3,R2
ST R3,AWINDOW
L R3,ABATCH
CHI R3,1
JNL *+8
LHI R3,1
CHI R3,IOVMAX
JNH *+8
LHI R3,IOVMAX
ST R3,ABATCH
L R3,ARETRY
CHI R3,1
JNL *+8
LHI R3,1
ST R3,ARETRY
L R3,AHBEAT
CHI R3,5
JNL *+8
LHI R3,5
ST R3,AHBEAT
SLL R3,1
C R3,AACKTO
JNH *+8
ST R3,AACKTO
L R3,APORT
LTR R3,R3
JNP CF010
C R3,=F'65535'
JNH CF020
CF010 MSG$
TXT$ 'SMFR004E INVALID PORT, USING 6110'
OUT$ 1
MVC APORT,=F'6110'
L R0,CFGBAD
AHI R0,1
ST R0,CFGBAD
CF020 CLC ARESL,=H'0'
JNE CF025
MSG$
TXT$ 'SMFR004E EMPTY RESOURCE, USING IFASMF.CICS110'
OUT$ 1
MVC ARESL,=H'14'
MVC ARES,=CL26'IFASMF.CICS110'
L R0,CFGBAD
AHI R0,1
ST R0,CFGBAD
CF025 LA R1,AHOST
LH R0,AHOSTL
JAS R14,IPPARSE
LTR R0,R0
JZ CF030
MSG$
TXT$ 'SMFR004E HOST MUST BE AN IPV4 ADDRESS: '
FLDH$ AHOST,AHOSTL
OUT$ 1
L R0,CFGBAD
AHI R0,1
ST R0,CFGBAD
L R15,=X'7F000001' 127.0.0.1
CF030 ST R15,AHOSTIP
CLC ALOCKL,=H'0' DEFAULT /tmp/smfreal.<RES>.lock
JNE CF040
MVC ALOCK(13),=C'/tmp/smfreal.'
LA R2,ALOCK+13
LH R3,ARESL
LR R1,R3
BCTR R1,0
EX R1,CFMVRES
AR R2,R3
MVC 0(5,R2),=C'.lock'
LA R3,18(,R3)
STH R3,ALOCKL
CF040 PR
CFMVRES MVC 0(0,R2),ARES
*
*---------------------------------------------------------------------
* SHOWCFG - SMFR002I
*---------------------------------------------------------------------
SHOWCFG BAKR R14,0
MSG$
TXT$ 'SMFR002I RESOURCE='
FLDH$ ARES,ARESL
TXT$ ' HOST='
FLDH$ AHOST,AHOSTL
TXT$ ' PORT='
DECF$ APORT
TXT$ ' SLOTS='
DECF$ ASLOTS
TXT$ ' WINDOW='
DECF$ AWINDOW
TXT$ ' BATCH='
DECF$ ABATCH
OUT$ 0
MSG$
TXT$ 'SMFR002I RETRY='
DECF$ ARETRY
TXT$ ' HEARTBEAT='
DECF$ AHBEAT
TXT$ ' ACKTIMEOUT='
DECF$ AACKTO
TXT$ ' DRAIN='
DECF$ ADRAIN
TXT$ ' STATINT='
DECF$ ASTATINT
TXT$ ' STATSEND='
DECF$ ASTATSND
TXT$ ' TRACE='
JAS R14,APPYN
TXT$ ' MAXRECS='
DEC$ AMAXREC
OUT$ 0
PR
*
***********************************************************************
* GETTER SUBTASK (SMFRGET) *
***********************************************************************
SMFRGET ENT$
L R9,0(,R1) -> ANCP OF THE MAIN TASK
L R9,0(,R9) ANCHOR
STORAGE OBTAIN,LENGTH=MAXREC,LOC=31
ST R1,SCRATCH
XC LASTMISS,LASTMISS
* CONNECT
GE010 CLI ASTOP,0
JNE GEEND
XC CNPB,CNPB
MVC CNPB(4),=C'CNPB'
MVC CNPB+4(2),=H'106'
MVI CNPB+7,1
MVC CNPB+12(2),ARESL
MVC CNPB+14(26),BLANKS
LH R1,ARESL
BCTR R1,0
EX R1,GEMVRES
L R15,=V(IFAMCON)
LA R1,PLCON
JAS R14,IFACALL
ICM R0,15,IRC
JZ GE020
MSG$
TXT$ 'SMFR011E IFAMCON '
FLDH$ ARES,ARESL
TXT$ ' RC='
HEX$ IRC+3,1
TXT$ ' RSN='
HEX$ IRSN+2,2
TXT$ ', RETRY IN '
DECF$ ARETRY
TXT$ 'S'
OUT$ 1
L R1,ARETRY
JAS R14,NAP
J GE010
GE020 MVC ATOKEN,CNPB+56
MVI ASMFCON,1
INC$ SSMFCON
MSG$
TXT$ 'SMFR010I CONNECTED TO IN-MEMORY RESOURCE '
FLDH$ ARES,ARESL
OUT$ 1
XC GTPB,GTPB
MVC GTPB(4),=C'GTPB'
MVC GTPB+4(2),=H'64'
MVI GTPB+7,1 FLAGS 0 = BLOCKING
MVC GTPB+16(16),CNPB+56
MVC GTPB+32(4),=A(MAXREC)
* GET LOOP
GE030 CLI ASTOP,0
JNE GEDSC
XC SLOTP,SLOTP RESERVE THE NEXT SLOT
LG R2,AQHEAD
LG R3,AQTAIL
LGR R4,R2
SGR R4,R3
LLGF R5,ASLOTS
CLGR R4,R5
JNL GE040 RING FULL
LGR R1,R2
AGHI R1,1
STG R1,NREC
JAS R14,SLOTADR
ST R15,SLOTP
LA R15,SLDATA(,R15)
ST R15,TARGET
J GE050
GE040 MVC TARGET,SCRATCH
GE050 XC GTPB+56(4),GTPB+56
MVC GTPB+60(4),TARGET
XC GTPB+52(4),GTPB+52
L R15,=V(IFAMGET)
LA R1,PLGET
JAS R14,IFACALL
ICM R0,15,IRC
JNZ GE060
JAS R14,GOTREC
J GE030
GE060 CLC IRC,=F'4'
JNE GE080
CLC IRSN,=X'00000401' MISSED DATA
JNE GE070
INC$ SMISSED
LG R2,SMISSED
LG R3,LASTMISS
LTGR R3,R3
JZ GE065
SGR R2,R3
CGHI R2,100
JL GE066
GE065 MVC LASTMISS,SMISSED
MSG$
TXT$ 'SMFR012W IFAMGET MISSED DATA ('
DEC$ SMISSED
TXT$ ')'
OUT$ 1
GE066 JAS R14,GOTREC
J GE030
GE070 CLC IRSN,=X'00000405' STOP IN PROGRESS
JE GEDSC
CLC IRSN,=X'00000406'
JE GEDSC
CLC IRSN,=X'00000408'
JE GEDSC
GE080 MSG$
TXT$ 'SMFR013E IFAMGET RC='
HEX$ IRC+3,1
TXT$ ' RSN='
HEX$ IRSN+2,2
OUT$ 1
* DISCONNECT
GEDSC MVI ASMFCON,0
XC DSPB,DSPB
MVC DSPB(4),=C'DSPB'
MVC DSPB+4(2),=H'24'
MVI DSPB+7,1
MVC DSPB+8(16),CNPB+56
L R15,=V(IFAMDSC)
LA R1,PLDSC
JAS R14,IFACALL
MSG$
TXT$ 'SMFR018I DISCONNECTED FROM '
FLDH$ ARES,ARESL
TXT$ ' RC='
HEX$ IRC+3,1
TXT$ ' RSN='
HEX$ IRSN+2,2
OUT$ 1
CLI ASTOP,0
JNE GEEND
L R1,ARETRY
JAS R14,NAP
J GE010
GEEND L R13,SAVEA+4
LM R14,R12,12(R13)
SLR R15,R15
BR R14
GEMVRES MVC CNPB+14(0),ARES
*
*---------------------------------------------------------------------
* GOTREC - RECORD RETURNED BY IFAMGET IN TARGET (SLOT OR SCRATCH)
*---------------------------------------------------------------------
GOTREC BAKR R14,0
L R4,GTPB+52 RETURNED LENGTH
LTR R4,R4
JNP GRRET
C R4,=A(MAXREC)
JH GRRET
L R2,TARGET
JAS R14,CLASSIFY
LTR R15,R15
JZ GRRET
ICM R3,15,SLOTP
JZ GR010
JAS R14,COMMIT
J GR020
GR010 JAS R14,DROPREC
GR020 LG R0,AMAXREC MAXRECS (TEST ONLY)
LTGR R0,R0
JZ GRRET
CLI ASTOP,0
JNE GRRET
LG R1,SSUB1
CLGR R1,R0
JL GRRET
MSG$
TXT$ 'SMFR017I MAXRECS='
DEC$ AMAXREC
TXT$ ' REACHED'
OUT$ 1
MVI ASTOP,1
POST ASTOPECB
GRRET PR
*
*---------------------------------------------------------------------
* CLASSIFY - R2 = RECORD, R4 = LENGTH. R15 = 1 TO FORWARD IT
*---------------------------------------------------------------------
CLASSIFY BAKR R14,0
INC$ SGETS
CHI R4,44
JL CLOTHER
CLI 5(R2),110 TYPE 110
JNE CLOTHER
CLC 22(2,R2),=H'1' SUBTYPE 1
JNE CLOTHER
L R5,28(,R2) OFFSET OF THE PRODUCT SECTION
CL R5,=F'44'
JL CLOTHER
LA R1,24(,R5)
CLR R1,R4
JH CLOTHER
INC$ SSUB1
AR R5,R2 R5 -> PRODUCT SECTION
LH R8,22(,R5) CLASS
ST R8,CLSW
CHI R8,1
JNE CF300
INC$ SDICTS
JAS R14,CACHEDIC
MSG$
TXT$ 'SMFR015I DICTIONARY RECEIVED FOR APPLID '
FLD$ 10(R5),8
OUT$ 1
J CF310
CF300 CHI R8,3
JNE CF310
INC$ SPERF
CF310 CLI ATRACE,0
JE CF320
ST R4,LENW
MSG$
TXT$ 'SMFR016I RECORD LEN='
DECF$ LENW
TXT$ ' APPLID='
FLD$ 10(R5),8
TXT$ ' CLASS='
DECF$ CLSW
OUT$ 0
CF320 LHI R15,1
PR
CLOTHER INC$ SOTHER
LHI R15,0
PR
*
*---------------------------------------------------------------------
* CACHEDIC - KEEP THE LAST DICTIONARY OF THE APPLID AT 10(R5)
* R2 = RECORD, R4 = LENGTH
*---------------------------------------------------------------------
CACHEDIC BAKR R14,0
ENQ (QNAME,RNDICT,E,8,STEP),RET=NONE
LA R3,ADICT
ICM R8,15,ADICTN
JZ CD020
CD010 CLC 0(8,R3),10(R5)
JE CD040
LA R3,16(,R3)
JCT R8,CD010
CD020 L R8,ADICTN NEW ENTRY (R3 = ENTRY N)
CHI R8,MAXDICT
JNL CD030
AHI R8,1
ST R8,ADICTN
J CD040
CD030 L R8,ADICTX FULL: REUSE IN ROTATION
LR R3,R8
SLL R3,4
LA R3,ADICT(R3)
AHI R8,1
N R8,=F'63'
ST R8,ADICTX
CD040 MVC 0(8,R3),10(R5)
ST R4,8(,R3)
L R0,12(,R3)
LR R1,R4
LR R14,R2
LR R15,R4
MVCL R0,R14
DEQ (QNAME,RNDICT,8,STEP),RET=NONE
PR
*
*---------------------------------------------------------------------
* COMMIT - R3 = SLOT, R4 = LENGTH, NREC = SEQUENCE. FRAME HEADER IN
* FRONT OF THE DATA, PUBLISH, WAKE THE SENDER IF IT WAITS
*---------------------------------------------------------------------
COMMIT BAKR R14,0
MVC 4(4,R3),MAGIC
MVI 8(R3),1 VERSION
MVI 9(R3),PT#REC
XC 10(2,R3),10(R3)
MVC 12(8,R3),NREC
ST R4,20(,R3)
ST R4,0(,R3)
LG R0,NREC
STG R0,AQHEAD
BCR 15,0 STORE -> LOAD ORDER (SEE SENDER)
ICM R0,15,AWAITING
JZ CM010
LHI R0,1
LHI R1,0
CS R0,R1,AWAITING
JNE CM010
INC$ SWAKES
JAS R14,WAKEUP
CM010 PR
*
*---------------------------------------------------------------------
* DROPREC - RING FULL
*---------------------------------------------------------------------
DROPREC BAKR R14,0
INC$ SDROP
LG R3,SDROP
CGHI R3,1
JE DR010
LGHI R2,0
LGHI R4,1000
DLGR R2,R4
LTGR R2,R2
JNZ DR020
DR010 MSG$
TXT$ 'SMFR014W RING FULL, '
DEC$ SDROP
TXT$ ' RECORDS DROPPED'
OUT$ 1
DR020 PR
*
***********************************************************************
* SENDER SUBTASK (SMFRSND) *
***********************************************************************
SMFRSND ENT$
L R9,0(,R1)
L R9,0(,R9)
CALL BPX1SPM,(FZERO,SIGPTR,FZERO,RV,RC,RSN),VL,MF=(E,CALLPL)
L R0,=A(MAXDICT*MAXREC)
STORAGE OBTAIN,LENGTH=(R0),LOC=31
ST R1,REPLAY
MVC FD,=F'-1'
XC RLEN,RLEN
XC FAILS,FAILS
XC STOPAT,STOPAT
XC LASTCLOS,LASTCLOS
XC LASTSTS,LASTSTS
NOW$ R2
STG R2,LASTSTAT
STG R2,LASTSEND
STG R2,LASTACK
* MAIN LOOP
SE010 NOW$ R2
STG R2,NOWUS
LG R3,AQHEAD
STG R3,HEADL
LG R3,AQSENT
STG R3,SENTL
LG R3,AQTAIL
STG R3,TAILL
CLI ASTOP,0
JE SE020
LG R3,STOPAT
LTGR R3,R3
JNZ SE015
LLGF R3,ADRAIN
MSGFI R3,1000000
AGR R3,R2
STG R3,STOPAT
SE015 CLC TAILL,HEADL
JE SEEND
ICM R0,15,FD
JM SEEND
CG R2,STOPAT
JNL SEEND
SE020 ICM R3,15,ASTATINT STATISTICS IN SYSPRINT
JZ SE030
LLGFR R3,R3
MSGFI R3,60000000
AG R3,LASTSTAT
CGR R2,R3
JL SE030
LHI R1,0
JAS R14,SHOWSTAT
MVC LASTSTAT,NOWUS
* (RE)CONNECT
SE030 ICM R0,15,FD
JNM SE100
LG R3,LASTCLOS
LTGR R3,R3
JZ SE040
LLGF R4,ARETRY
MSGFI R4,1000000
AGR R4,R3 END OF THE BACKOFF
SGR R4,R2
JNP SE040
LGR R1,R4
LGHI R0,0
DLG R0,=FD'1000000'
AHI R1,1
JAS R14,NAP
J SE010
SE040 JAS R14,CONNECT
ST R15,FD
LTR R15,R15
JNM SE050
L R3,FAILS
AHI R3,1
ST R3,FAILS
CHI R3,1
JE SE045
SLR R2,R2
D R2,=F'30'
LTR R2,R2
JNZ SE046
SE045 MSG$
TXT$ 'SMFR021W COLLECTOR '
FLDH$ AHOST,AHOSTL
TXT$ ':'
DECF$ APORT
TXT$ ' UNAVAILABLE, RETRY EVERY '
DECF$ ARETRY
TXT$ 'S'
OUT$ 1
SE046 L R1,ARETRY
JAS R14,NAP
J SE010
SE050 JAS R14,HELLO
LTR R15,R15
JZ SE060
CLOSE$ 'HELLO FAILED'
L R1,ARETRY
JAS R14,NAP
J SE010
SE060 XC FAILS,FAILS
INC$ SCONNECT
MVI ACOLLCON,1
XC RLEN,RLEN
MVC AQSENT,AQTAIL RESEND UNACKED RECORDS
MVC SENTL,AQTAIL
NOW$ R2
STG R2,NOWUS
STG R2,LASTSEND
STG R2,LASTACK
STG R2,LASTSTS
ICM R0,15,ASTATSND
JZ SE070
JAS R14,SENDSTAT
LTR R15,R15
JZ SE070
CLOSE$ 'STATUS FAILED'
J SE010
SE070 MSG$
TXT$ 'SMFR020I CONNECTED TO COLLECTOR '
FLDH$ AHOST,AHOSTL
TXT$ ':'
DECF$ APORT
TXT$ ', RESENDING FROM SEQ '
LG R3,SENTL
AGHI R3,1
DECR$ R3
OUT$ 1
* SEND A BATCH
SE100 XC WAITING,WAITING
LG R2,SENTL
AGHI R2,1 FIRST
LG R3,HEADL LAST = MIN(HEAD, TAIL+WINDOW,
LLGF R4,AWINDOW FIRST+BATCH-1)
AG R4,TAILL
CLGR R3,R4
JNH *+8
LGR R3,R4
LLGF R4,ABATCH
AGR R4,R2
AGHI R4,-1
CLGR R3,R4
JNH *+8
LGR R3,R4
CLGR R2,R3
JH SE200 NOTHING TO SEND
STG R3,LASTB
JAS R14,SBATCH
LTR R15,R15
JZ SE110
LHI R0,0
JAS R14,CLOSEC
J SE010
SE110 LG R3,LASTB
CLG R3,AQSENT
JNH *+10
STG R3,AQSENT
MVC LASTSEND,NOWUS
MVC CANSEND,=F'1'
XC TIMEOUT,TIMEOUT
J SE300
* IDLE: SLEEP UNTIL A DEADLINE
SE200 XC CANSEND,CANSEND
LG R2,NOWUS
LLGF R3,AHBEAT
MSGFI R3,1000000
AG R3,LASTSEND DL = HEARTBEAT
ICM R4,15,ASTATSND
JZ SE210
LLGFR R4,R4
MSGFI R4,1000000
AG R4,LASTSTS
CGR R4,R3
JNL SE210
LGR R3,R4
SE210 CLC SENTL,TAILL
JE SE220
LLGF R4,AACKTO
MSGFI R4,1000000
AG R4,LASTACK
CGR R4,R3
JNL SE220
LGR R3,R4
SE220 ICM R4,15,ASTATINT
JZ SE230
LLGFR R4,R4
MSGFI R4,60000000
AG R4,LASTSTAT
CGR R4,R3
JNL SE230
LGR R3,R4
SE230 CLI ASTOP,0
JE SE240
LG R4,STOPAT
CGR R4,R3
JNL SE240
LGR R3,R4
SE240 SGR R3,R2 MICROSECONDS UNTIL THE DEADLINE
JNM *+8
LGHI R3,0
CGFI R3,60000000
JNH *+10
LGFI R3,60000000
LGR R1,R3
LGHI R0,0
DLG R0,=FD'1000'
ST R1,TIMEOUT
* IDLE HANDSHAKE WITH THE GETTER (COMMIT): SET WAITING, THEN
* LOOK AT THE HEAD AGAIN - NO WAKE-UP CAN BE LOST
MVC AWAITING,=F'1'
MVC WAITING,=F'1'
BCR 15,0
LG R2,AQSENT
CG R2,AQHEAD
JNL SE300 CAUGHT UP: SLEEP
XC AWAITING,AWAITING
XC WAITING,WAITING
AGHI R2,1
SG R2,AQTAIL
CLGF R2,AWINDOW
JH SE300 WINDOW FULL: THE ACK WAKES US
XC TIMEOUT,TIMEOUT NEW WORK ARRIVED
* POLL SOCKET + PIPE
SE300 MVC PFD0,FD
MVC PFD0+4(4),=X'00030000'
MVC PFD1,AWAKER
MVC PFD1+4(4),=X'00030000'
CALL BPX1POL,(PFDPTR,FTWO,TIMEOUT,RV,RC,RSN),VL,MF=(E,CALLPL)
ICM R0,15,WAITING
JZ SE310
XC AWAITING,AWAITING
SE310 L R0,RV
LTR R0,R0
JNM SE320
CLC RC,=A(EINTR)
JE SE320
CLOSE$ 'POLL FAILED'
J SE010
SE320 TM PFD1+7,X'03' PIPE: DRAIN THE WAKE-UP BYTES
JZ SE330
LARL R2,PIPEBUF
ST R2,BUFPTRW
CALL BPX1RED,(AWAKER,BUFPTRW,FZERO,F64,RV2,RC2,RSN2),VL, X
MF=(E,CALLPL)
SE330 TM PFD0+7,X'63' SOCKET: IN, HUP, ERR
JZ SE400
LARL R2,RBUF
A R2,RLEN
ST R2,BUFPTRW
LHI R3,RBUFSZ
S R3,RLEN
ST R3,WORKF
CALL BPX1RED,(FD,BUFPTRW,FZERO,WORKF,RV,RC,RSN),VL,MF=(E, X
CALLPL)
L R3,RV
LTR R3,R3
JP SE340
JZ SE335
LHI R0,0
JAS R14,CLOSEC
J SE010
SE335 CLOSE$ 'CLOSED BY COLLECTOR'
J SE010
SE340 A R3,RLEN
ST R3,RLEN
JAS R14,ACKS
LTR R15,R15
JZ SE400
CLOSE$ 'PROTOCOL ERROR'
J SE010
* STATUS / HEARTBEAT / ACK TMO
SE400 NOW$ R2
STG R2,NOWUS
ICM R3,15,ASTATSND
JZ SE410
LLGFR R3,R3
MSGFI R3,1000000
AG R3,LASTSTS
CGR R2,R3
JL SE410
JAS R14,SENDSTAT
LTR R15,R15
JZ SE405
CLOSE$ 'STATUS FAILED'
J SE010
SE405 MVC LASTSTS,NOWUS
MVC LASTSEND,NOWUS
SE410 ICM R0,15,CANSEND
JNZ SE420
LLGF R3,AHBEAT
MSGFI R3,1000000
AG R3,LASTSEND
CG R3,NOWUS
JH SE420
LHI R2,PT#HB
LGHI R3,0
LHI R4,0
LHI R5,0
JAS R14,SENDFRM
LTR R15,R15
JZ SE415
CLOSE$ 'HEARTBEAT FAILED'
J SE010
SE415 MVC LASTSEND,NOWUS
SE420 LG R2,AQSENT
CG R2,AQTAIL
JNE SE430
MVC LASTACK,NOWUS
J SE010
SE430 LLGF R3,AACKTO
MSGFI R3,1000000
AG R3,LASTACK
CG R3,NOWUS
JH SE010
CLOSE$ 'ACK TIMEOUT'
J SE010
* END
SEEND ICM R0,15,FD
JM SE510
CALL BPX1CLO,(FD,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
MVC FD,=F'-1'
MVI ACOLLCON,0
SE510 LG R2,AQHEAD
SG R2,AQTAIL
JZ SE520
MSG$
TXT$ 'SMFR023W '
DECR$ R2
TXT$ ' RECORDS NOT ACKNOWLEDGED AT STOP'
OUT$ 1
SE520 L R13,SAVEA+4
LM R14,R12,12(R13)
SLR R15,R15
BR R14
*
*---------------------------------------------------------------------
* ACKS - PARSE 20-BYTE FRAMES IN RBUF. R15 = 0 OK, 8 PROTOCOL ERROR
*---------------------------------------------------------------------
ACKS BAKR R14,0
LARL R2,RBUF R2 = FRAME
L R3,RLEN R3 = BYTES LEFT
AK010 CHI R3,20
JL AK030
CLC 0(4,R2),MAGIC
JNE AK020
ICM R0,15,16(R2) PAYLOAD MUST BE EMPTY
JNZ AK020
CLI 5(R2),PT#ACK
JNE AK015
LG R4,8(,R2)
CLG R4,AQTAIL
JNH AK015
CLG R4,AQSENT
JH AK015
STG R4,AQTAIL
MVC LASTACK,NOWUS
AK015 LA R2,20(,R2)
AHI R3,-20
J AK010
AK020 LHI R15,8
PR
AK030 ST R3,RLEN KEEP A PARTIAL FRAME
LTR R3,R3
JZ AK040
LARL R4,RBUF
LR R5,R3
LR R14,R2
LR R15,R3
MVCL R4,R14
AK040 LHI R15,0
PR
*
*---------------------------------------------------------------------
* CONNECT - SOCKET + CONNECT + OPTIONS. R15 = FD OR -1
*---------------------------------------------------------------------
CONNECT BAKR R14,0
CALL BPX1SOC,(FAINET,FSTREAM,FZERO,FONE,SOCKV,RV,RC,RSN),VL, X
MF=(E,CALLPL)
L R0,RV
LTR R0,R0
JM CN020
XC SADDR,SADDR
MVI SADDR,16
MVI SADDR+1,2 AF_INET
MVC SADDR+2(2),APORT+2
MVC SADDR+4(4),AHOSTIP
CALL BPX1CON,(SOCKV,F16,SADDR,RV,RC,RSN),VL,MF=(E,CALLPL)
L R0,RV
LTR R0,R0
JNM CN010
CALL BPX1CLO,(SOCKV,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
J CN020
CN010 CALL BPX1OPT,(SOCKV,FTWO,FTCP,FONE,F4,FONE,RV2,RC2,RSN2),VL, X
MF=(E,CALLPL)
CALL BPX1OPT,(SOCKV,FTWO,FSOLSOCK,FKEEPAL,F4,FONE,RV2,RC2, X
RSN2),VL,MF=(E,CALLPL)
L R15,SOCKV
PR
CN020 LHI R15,-1
PR
*
*---------------------------------------------------------------------
* CLOSEC - CLOSE THE COLLECTOR SOCKET. R1/R0 = REASON (R0=0: ERRNO)
*---------------------------------------------------------------------
CLOSEC BAKR R14,0
LR R2,R1
LR R3,R0
CALL BPX1CLO,(FD,RV2,RC2,RSN2),VL,MF=(E,CALLPL)
MVC FD,=F'-1'
MVI ACOLLCON,0
NOW$ R4
STG R4,LASTCLOS
MSG$
TXT$ 'SMFR021W COLLECTOR CONNECTION CLOSED: '
LTR R3,R3
JZ CC010
LR R1,R2
LR R0,R3
JAS R14,APPTXT
J CC020
CC010 TXT$ 'ERRNO='
DECF$ RC
TXT$ ' RSN='
HEX$ RSN,4
CC020 OUT$ 1
PR
*
*---------------------------------------------------------------------
* HELLO - HELLO FRAME + REPLAY OF THE CACHED DICTIONARIES. R15=0 OK
*---------------------------------------------------------------------
HELLO BAKR R14,0
MSG$
TXT$ 'PRODUCT=SMFREAL VERSION=2.0 SYSNAME='
FLD$ ASYSN,8
TXT$ ' JOBNAME='
FLD$ AJOBN,8
TXT$ ' JOBID='
JAS R14,APPJOBID
TXT$ ' RESOURCE='
FLDH$ ARES,ARESL
TXT$ ' INSTANCE='
HEX$ AINST,8
LHI R2,PT#HELLO
LGHI R3,0
LARL R4,MSGBUF
L R5,MSGLEN
JAS R14,SENDFRM
LTR R15,R15
JNZ HE090
* COPY THE DICTIONARIES
ENQ (QNAME,RNDICT,E,8,STEP),RET=NONE
L R2,ADICTN
ST R2,NREPLAY
LTR R2,R2
JZ HE020
LA R3,ADICT
L R4,REPLAY
LA R5,REPLEN
HE010 L R1,8(,R3)
ST R1,0(,R5)
LR R0,R4
L R14,12(,R3)
LR R15,R1
MVCL R0,R14
AL R4,=A(MAXREC)
LA R3,16(,R3)
LA R5,4(,R5)
JCT R2,HE010
HE020 DEQ (QNAME,RNDICT,8,STEP),RET=NONE
L R8,NREPLAY
LTR R8,R8
JZ HE080
L R4,REPLAY
LA R1,REPLEN
ST R1,REPPTR
HE030 L R1,REPPTR
L R5,0(,R1)
LA R1,4(,R1)
ST R1,REPPTR
LHI R2,PT#DICT
LGHI R3,0
JAS R14,SENDFRM
LTR R15,R15
JNZ HE090
AL R4,=A(MAXREC)
JCT R8,HE030
MSG$
TXT$ 'SMFR022I '
DECF$ NREPLAY
TXT$ ' DICTIONARIES REPLAYED'
OUT$ 0
HE080 LHI R15,0
PR
HE090 LHI R15,8
PR
*
*---------------------------------------------------------------------
* SENDFRM - CONTROL FRAME: R2 TYPE, R3 SEQ (64), R4/R5 DATA/LENGTH
*---------------------------------------------------------------------
SENDFRM BAKR R14,0
LARL R8,CHDR
MVC 0(4,R8),MAGIC
MVI 4(R8),1
STC R2,5(,R8)
XC 6(2,R8),6(R8)
STG R3,8(,R8)
ST R5,16(,R8)
LARL R1,IOV
ST R8,0(,R1)
LHI R0,20
ST R0,4(,R1)
LHI R3,1
LTR R5,R5
JZ SF010
ST R4,8(,R1)
ST R5,12(,R1)
LHI R3,2
SF010 LR R2,R1
JAS R14,WVALL
LTR R15,R15
JNZ SF020
LLGFR R0,R5
AGHI R0,20
AG R0,SSENTB
STG R0,SSENTB
SF020 PR
*
*---------------------------------------------------------------------
* SBATCH - RECORDS R2 (FIRST) .. R3 (LAST) IN A SINGLE WRITEV
*---------------------------------------------------------------------
SBATCH BAKR R14,0
LARL R8,IOV
LHI R4,0 COUNT
LGHI R5,0 BYTES
SB010 CLGR R2,R3
JH SB020
LGR R1,R2
JAS R14,SLOTADR
LA R0,4(,R15) HEADER + DATA ARE CONTIGUOUS
ST R0,0(,R8)
L R0,0(,R15)
AHI R0,20
ST R0,4(,R8)
ALGFR R5,R0
LA R8,8(,R8)
AHI R4,1
AGHI R2,1
J SB010
SB020 LARL R2,IOV
LR R3,R4
JAS R14,WVALL
LTR R15,R15
JNZ SB030
LLGFR R0,R4
AG R0,SSENTR
STG R0,SSENTR
AG R5,SSENTB
STG R5,SSENTB
INC$ SBATCHES
LHI R15,0
SB030 PR
*
*---------------------------------------------------------------------
* WVALL - WRITEV UNTIL EVERY BYTE IS OUT. R2 = IOV, R3 = COUNT
*---------------------------------------------------------------------
WVALL BAKR R14,0
WV010 LTR R3,R3
JNP WV090
ST R3,WORKF
CALL BPX1WRV,(FD,WORKF,(R2),FZERO,FZERO,RV,RC,RSN),VL,MF=(E, X
CALLPL)
L R4,RV
LTR R4,R4
JNM WV020
CLC RC,=A(EINTR)
JE WV010
LHI R15,-1
PR
WV020 LTR R3,R3 SKIP THE ENTRIES WRITTEN
JNP WV090
CL R4,4(,R2)
JL WV030
S R4,4(,R2)
LA R2,8(,R2)
BCTR R3,0
J WV020
WV030 LTR R4,R4 PARTIAL ENTRY
JZ WV010
L R0,0(,R2)
AR R0,R4
ST R0,0(,R2)
L R0,4(,R2)
SR R0,R4
ST R0,4(,R2)
J WV010
WV090 LHI R15,0
PR
*
*---------------------------------------------------------------------
* SENDSTAT - STATUS FRAME (EBCDIC KEY=VALUE). R15 = 0 OK
*---------------------------------------------------------------------
SENDSTAT BAKR R14,0
MSG$
TXT$ 'SMF='
CLI ASMFCON,0
JE SS010
TXT$ 'CONNECTED'
J SS020
SS010 TXT$ 'DISCONNECTED'
SS020 TXT$ ' RESOURCE='
FLDH$ ARES,ARESL
TXT$ ' GETS='
DEC$ SGETS
TXT$ ' SUB1='
DEC$ SSUB1
TXT$ ' DICT='
DEC$ SDICTS
TXT$ ' PERF='
DEC$ SPERF
TXT$ ' OTHER='
DEC$ SOTHER
TXT$ ' MISSED='
DEC$ SMISSED
TXT$ ' DROPPED='
DEC$ SDROP
JAS R14,APPQUEUE
TXT$ ' SENT='
DEC$ SSENTR
TXT$ ' SENTKB='
LG R2,SSENTB
SRLG R2,R2,10
DECR$ R2
TXT$ ' CONNECTS='
DEC$ SCONNECT
TXT$ ' SMFCONNECTS='
DEC$ SSMFCON
TXT$ ' SLOTS='
DECF$ ASLOTS
TXT$ ' WINDOW='
DECF$ AWINDOW
TXT$ ' BATCH='
DECF$ ABATCH
TXT$ ' BATCHES='
DEC$ SBATCHES
TXT$ ' WAKES='
DEC$ SWAKES
TXT$ ' TRACE='
JAS R14,APPYN
TXT$ ' STARTED='
LA R1,ASTARTT
LHI R0,19
JAS R14,APPTXT
TXT$ ' UPTIME='
NOW$ R3
SG R3,ASTARTUS
LGR R1,R3
LGHI R0,0
DLG R0,=FD'1000000'
DECR$ R1
TXT$ ' VERSION=2.0 JOBNAME='
FLD$ AJOBN,8
TXT$ ' JOBID='
JAS R14,APPJOBID
TXT$ ' SYSNAME='
FLD$ ASYSN,8
LHI R2,PT#STAT
LGHI R3,0
LARL R4,MSGBUF
L R5,MSGLEN
JAS R14,SENDFRM
PR
*
***********************************************************************
* SHARED ROUTINES *
***********************************************************************
*---------------------------------------------------------------------
* SHOWSTAT - SMFR030I-033I. R1 = 1 ALSO ON THE CONSOLE
*---------------------------------------------------------------------
SHOWSTAT BAKR R14,0
LR R8,R1
MSG$
TXT$ 'SMFR030I SMF '
FLDH$ ARES,ARESL
CLI ASMFCON,0
JE ST010
TXT$ ' CONNECTED'
J ST020
ST010 TXT$ ' DISCONNECTED'
ST020 TXT$ ' COLLECTOR '
FLDH$ AHOST,AHOSTL
TXT$ ':'
DECF$ APORT
CLI ACOLLCON,0
JE ST030
TXT$ ' CONNECTED'
J ST040
ST030 TXT$ ' DISCONNECTED'
ST040 LR R0,R8
JAS R14,LOGOUT
MSG$
TXT$ 'SMFR031I GETS='
DEC$ SGETS
TXT$ ' 110-1='
DEC$ SSUB1
TXT$ ' DICT='
DEC$ SDICTS
TXT$ ' PERF='
DEC$ SPERF
TXT$ ' OTHER='
DEC$ SOTHER
TXT$ ' MISSED='
DEC$ SMISSED
LR R0,R8
JAS R14,LOGOUT
MSG$
TXT$ 'SMFR032I'
JAS R14,APPQUEUE
TXT$ ' DROPPED='
DEC$ SDROP
TXT$ ' SENT='
DEC$ SSENTR
TXT$ ' KB='
LG R2,SSENTB
SRLG R2,R2,10
DECR$ R2
LR R0,R8
JAS R14,LOGOUT
MSG$
TXT$ 'SMFR033I BATCHES='
DEC$ SBATCHES
TXT$ ' (AVG '
LG R3,SSENTR
LG R4,SBATCHES
LGHI R2,0
LTGR R4,R4
JZ ST050
DLGR R2,R4
J ST060
ST050 LGHI R3,0
ST060 DECR$ R3
TXT$ ' RECORDS) WAKES='
DEC$ SWAKES
LR R0,R8
JAS R14,LOGOUT
PR
*
*---------------------------------------------------------------------
* APPQUEUE - ' QUEUED=n INFLIGHT=n ACKED=n'
*---------------------------------------------------------------------
APPQUEUE BAKR R14,0
LG R2,AQHEAD
LG R3,AQSENT
LG R4,AQTAIL
TXT$ ' QUEUED='
LGR R5,R2
SGR R5,R4
DECR$ R5
TXT$ ' INFLIGHT='
LGR R5,R3
SGR R5,R4
JNM *+8
LGHI R5,0
DECR$ R5
TXT$ ' ACKED='
DECR$ R4
PR
*
APPYN BAKR R14,0 'Y' OR 'N' FOR THE TRACE FLAG
CLI ATRACE,0
JE AY010
TXT$ 'Y'
PR
AY010 TXT$ 'N'
PR
*
APPJOBID BAKR R14,0 JOB ID OR '-'
CLI AJOBID,C' '
JNH AJ010
FLD$ AJOBID,8
PR
AJ010 TXT$ '-'
PR
*
*---------------------------------------------------------------------
* IFACALL - CALL THE IFAM SERVICE IN R15 WITH THE 64-BIT PLIST IN R1
* (AMODE 64, R13 -> F4SA). RETURNS IN AMODE 31
*---------------------------------------------------------------------
IFACALL BAKR R14,0
MVC IRC,=F'-1'
MVC IRSN,=F'-1'
LLGTR R1,R1
LLGTR R15,R15
LARL R13,F4SA
LLGTR R13,R13
SAM64
BASR R14,R15
SAM31
PR
*
*---------------------------------------------------------------------
* SLOTADR - R1 = SEQUENCE (64). R15 = SLOT ADDRESS
*---------------------------------------------------------------------
SLOTADR BAKR R14,0
LGR R3,R1
LGHI R2,0
LLGF R4,ASLOTS
DLGR R2,R4 R2 = SEQ MOD SLOTS
MSFI R2,SLOTSZ
A R2,ARING
LR R15,R2
PR
*
*---------------------------------------------------------------------
* WAKEUP - ONE BYTE INTO THE PIPE (WAKES THE SENDER'S POLL)
*---------------------------------------------------------------------
WAKEUP BAKR R14,0
ICM R0,15,AWAKEW
JM WK010
CALL BPX1WRT,(AWAKEW,ONEPTR,FZERO,FONE,RVW,RCW,RSNW),VL, X
MF=(E,CALLPL)
WK010 PR
*
*---------------------------------------------------------------------
* NAP - SLEEP R1 SECONDS (1 SECOND STEPS, ENDS EARLY AT STOP)
*---------------------------------------------------------------------
NAP BAKR R14,0
LTR R3,R1
JNP NP020
NP010 CLI ASTOP,0
JNE NP020
STIMER WAIT,BINTVL=ONESEC
JCT R3,NP010
NP020 PR
*
*---------------------------------------------------------------------
* NUMPARSE - R1/R0 = DECIMAL TEXT. R15 = VALUE (64), R0 = 0 OK/8 BAD
*---------------------------------------------------------------------
NUMPARSE BAKR R14,0
LTR R3,R0
JNP NU090
CHI R3,18
JH NU090
LGHI R15,0
NU010 LLC R2,0(,R1)
CHI R2,240
JL NU090
CHI R2,249
JH NU090
AHI R2,-240
MGHI R15,10
AGFR R15,R2
LA R1,1(,R1)
JCT R3,NU010
LHI R0,0
PR
NU090 LHI R0,8
PR
*
*---------------------------------------------------------------------
* IPPARSE - R1/R0 = A.B.C.D. R15 = ADDRESS, R0 = 0 OK/8 BAD
*---------------------------------------------------------------------
IPPARSE BAKR R14,0
LTR R3,R0 R3 = CHARACTERS LEFT
JNP IP090
LR R2,R1
LHI R4,4 OCTETS
SLR R15,R15
IP010 SLR R5,R5 OCTET VALUE
LHI R8,0 DIGITS
IP020 LTR R3,R3
JNP IP030
CLI 0(R2),C'.'
JE IP030
LLC R1,0(,R2)
CHI R1,240
JL IP090
CHI R1,249
JH IP090
AHI R1,-240
MHI R5,10
AR R5,R1
AHI R8,1
LA R2,1(,R2)
BCTR R3,0
J IP020
IP030 LTR R8,R8
JZ IP090
CHI R5,255
JH IP090
SLL R15,8
OR R15,R5
BCTR R4,0
LTR R4,R4
JZ IP040
LTR R3,R3 NEED A DOT AND MORE
JNP IP090
LA R2,1(,R2)
BCTR R3,0
J IP010
IP040 LTR R3,R3 NOTHING AFTER THE 4TH OCTET
JNZ IP090
LHI R0,0
PR
IP090 LHI R0,8
PR
*
*---------------------------------------------------------------------
* FMTTS - R1 -> 19 BYTES 'YYYY-MM-DD HH:MM:SS' (LOCAL TIME)
*---------------------------------------------------------------------
FMTTS BAKR R14,0
LR R8,R1
TIME DEC,TIMEA,ZONE=LT,LINKAGE=SYSTEM,DATETYPE=YYYYMMDD
MVC TSPK(4),TIMEA+8 YYYYMMDD
MVI TSPK+4,X'0F'
UNPK TSZ(9),TSPK(5)
MVC 0(4,R8),TSZ
MVI 4(R8),C'-'
MVC 5(2,R8),TSZ+4
MVI 7(R8),C'-'
MVC 8(2,R8),TSZ+6
MVI 10(R8),C' '
MVC TSPK(3),TIMEA HHMMSS
MVI TSPK+3,X'0F'
UNPK TSZ(7),TSPK(4)
MVC 11(2,R8),TSZ
MVI 13(R8),C':'
MVC 14(2,R8),TSZ+2
MVI 16(R8),C':'
MVC 17(2,R8),TSZ+4
PR
*
*---------------------------------------------------------------------
* MESSAGE BUILDER: APPTXT (R1/R0), APPFLD (TRIMMED), APPDEC (R1->D),
* APPDECF (R1->F), APPHEX (R1/R0)
*---------------------------------------------------------------------
APPTXT BAKR R14,0
L R8,MSGLEN
LR R3,R0 LENGTH
LR R2,R1 SOURCE
LHI R5,MSGMAX
SR R5,R8 ROOM
JNP AT090
CR R3,R5
JNH AT010
LR R3,R5
AT010 LTR R3,R3
JNP AT090
LARL R4,MSGBUF
AR R4,R8
LR R5,R3
AR R8,R3
ST R8,MSGLEN
MVCL R4,R2
AT090 PR
*
APPFLD BAKR R14,0
AF010 LTR R0,R0
JNP AF090
LR R3,R1
AR R3,R0
BCTR R3,0
CLI 0(R3),C' '
JE AF020
CLI 0(R3),X'00'
JNE AF030
AF020 BCTR R0,0
J AF010
AF030 JAS R14,APPTXT
AF090 PR
*
APPDECF BAKR R14,0
LLGF R2,0(,R1)
STG R2,DECTMP
LA R1,DECTMP
JAS R14,APPDEC
PR
*
APPDEC BAKR R14,0
LG R3,0(,R1)
LARL R4,DECBUF+24
LHI R5,0
LGHI R8,10
AD010 LGHI R2,0
DLGR R2,R8 R3 = QUOTIENT, R2 = DIGIT
AHI R2,240
BCTR R4,0
STC R2,0(,R4)
AHI R5,1
LTGR R3,R3
JNZ AD010
LR R1,R4
LR R0,R5
JAS R14,APPTXT
PR
*
APPHEX BAKR R14,0
LR R2,R1
LTR R3,R0
JNP AH090
AH010 UNPK HEX3(3),0(2,R2)
TR HEX3(2),HEXTAB-240
LA R1,HEX3
LHI R0,2
JAS R14,APPTXT
LA R2,1(,R2)
JCT R3,AH010
AH090 PR
*
*---------------------------------------------------------------------
* LOGOUT - MSGBUF TO SYSPRINT (TIMESTAMPED) AND, IF R0=1, TO THE
* CONSOLE (WTO ROUTCDE=2 DESC=6)
*---------------------------------------------------------------------
LOGOUT BAKR R14,0
LR R8,R0
LARL R4,LOGREC
LA R1,5(,R4)
JAS R14,FMTTS
MVI 4(R4),C' '
MVI 24(R4),C' '
L R5,MSGLEN
CHI R5,230
JNH *+8
LHI R5,230
LA R0,25(,R4)
LARL R14,MSGBUF
LR R1,R5
LR R15,R5
MVCL R0,R14
LA R5,25(,R5)
STH R5,0(,R4) RDW
XC 2(2,R4),2(R4)
ICM R2,15,APRTDCB
JZ LO010
ENQ (QNAME,RNLOG,E,8,STEP),RET=NONE
PUT (R2),(R4)
DEQ (QNAME,RNLOG,8,STEP),RET=NONE
LO010 LTR R8,R8
JZ LO090
L R5,MSGLEN
CHI R5,125
JNH *+8
LHI R5,125
STH R5,WTOLEN
LTR R5,R5
JNP LO090
BCTR R5,0
LARL R14,MSGBUF
EX R5,LOMVC
WTO TEXT=WTOLEN,ROUTCDE=(2),DESC=(6)
LO090 PR
LOMVC MVC WTOTXT(0),0(R14)
*
***********************************************************************
* STATIC DATA (EVERY TASK HAS ITS OWN COPY OF THE MODULE) *
***********************************************************************
DATA LOCTR
DS 0D
SAVEA DC 18F'0'
RETC DC F'0'
ANCP DC A(0) ANCHOR ADDRESS (MAIN COPY)
ANSWER DC A(0)
WORKF DC F'0'
LENW DC F'0'
CLSW DC F'0'
CFGBAD DC F'0'
MSGLEN DC F'0'
WTOLEN DC H'0'
WTOTXT DC CL126' '
HOLDLEN DC H'0'
DS 0D
TODW DC D'0'
DECTMP DC D'0'
ECBL DC 4A(0)
* Z/OS UNIX SERVICES
RV DC F'0'
RC DC F'0'
RSN DC F'0'
RV2 DC F'0'
RC2 DC F'0'
RSN2 DC F'0'
RVW DC F'0'
RCW DC F'0'
RSNW DC F'0'
DS 0D
RVD DC D'0'
DZERO DC FD'0'
FZERO DC F'0'
FONE DC F'1'
FTWO DC F'2'
F4 DC F'4'
F16 DC F'16'
F64 DC F'64'
F255 DC F'255'
FAINET DC F'2'
FSTREAM DC F'1'
FTCP DC F'6'
FSOLSOCK DC X'0000FFFF'
FKEEPAL DC F'8'
FOPNOPT DC X'00000083' O_CREAT + O_RDWR
FMODE DC X'000001B6' 0666
FSETLK DC F'6'
FGETLK DC F'5'
BUFPTRW DC A(0)
ONEPTR DC A(ONEBYTE)
ONEBYTE DC C'W'
NLCHAR DC X'15'
DS 0D
SIGMASK DC XL8'0008000000000000' SIGPIPE (13)
SIGPTR DC A(SIGMASK)
BRLKPTR DC A(BRLK)
BRLK DC XL24'00' BPXYBRLK
SOCKV DC F'0'
SADDR DC XL16'00'
PFDPTR DC A(PFD0)
PFD0 DC F'-1',XL4'00' POLLFD: SOCKET
PFD1 DC F'-1',XL4'00' POLLFD: PIPE
TIMEOUT DC F'0'
* IFAM SERVICES (AMODE 64)
DS 0D
IRC DC F'0'
IRSN DC F'0'
CNPB DC XL106'00'
DS 0D
GTPB DC XL64'00'
DSPB DC XL24'00'
DS 0D
PLCON DC AD(CNPB),AD(IRC),AD(IRSN)
PLGET DC AD(GTPB),AD(IRC),AD(IRSN)
PLDSC DC AD(DSPB),AD(IRC),AD(IRSN)
* GETTER
DS 0D
NREC DC D'0'
LASTMISS DC D'0'
SLOTP DC A(0)
TARGET DC A(0)
SCRATCH DC A(0)
* SENDER
DS 0D
NOWUS DC D'0'
HEADL DC D'0'
SENTL DC D'0'
TAILL DC D'0'
LASTB DC D'0'
LASTSEND DC D'0'
LASTACK DC D'0'
LASTSTAT DC D'0'
LASTSTS DC D'0'
LASTCLOS DC D'0'
STOPAT DC D'0'
FD DC F'-1'
RLEN DC F'0'
FAILS DC F'0'
WAITING DC F'0'
CANSEND DC F'0'
REPLAY DC A(0)
NREPLAY DC F'0'
REPPTR DC A(0)
REPLEN DC (MAXDICT)F'0'
* CONSTANTS
MAGIC DC X'534D4652' 'SMFR' IN ASCII
QNAME DC CL8'SMFREAL'
RNLOG DC CL8'LOG'
RNDICT DC CL8'DICT'
CALLPL DC 12A(0) PARAMETER LIST (CALL MF=E)
ONESEC DC F'100'
HEXTAB DC C'0123456789ABCDEF'
HEX3 DC CL3' '
TIMEA DC XL16'00'
TSPK DC XL5'00'
TSZ DC CL9' '
TSWORK DC CL19' '
CMDW DC CL64' '
KEYW DC CL16' '
LINE DC CL72' '
DC CL8' '
BLANKS DC CL256' '
* CONFIG KEYS
CFGTAB DS 0H
DC AL1(8),CL10'RESOURCE',C'S',AL2(ARESL-ANC),AL2(26)
CFGTABL EQU *-CFGTAB
DC AL1(4),CL10'HOST',C'S',AL2(AHOSTL-ANC),AL2(64)
DC AL1(4),CL10'PORT',C'F',AL2(APORT-ANC),AL2(0)
DC AL1(5),CL10'SLOTS',C'F',AL2(ASLOTS-ANC),AL2(0)
DC AL1(6),CL10'WINDOW',C'F',AL2(AWINDOW-ANC),AL2(0)
DC AL1(5),CL10'BATCH',C'F',AL2(ABATCH-ANC),AL2(0)
DC AL1(5),CL10'RETRY',C'F',AL2(ARETRY-ANC),AL2(0)
DC AL1(9),CL10'HEARTBEAT',C'F',AL2(AHBEAT-ANC),AL2(0)
DC AL1(10),CL10'ACKTIMEOUT',C'F',AL2(AACKTO-ANC),AL2(0)
DC AL1(5),CL10'DRAIN',C'F',AL2(ADRAIN-ANC),AL2(0)
DC AL1(7),CL10'STATINT',C'F',AL2(ASTATINT-ANC),AL2(0)
DC AL1(8),CL10'STATSEND',C'F',AL2(ASTATSND-ANC),AL2(0)
DC AL1(5),CL10'TRACE',C'Y',AL2(ATRACE-ANC),AL2(0)
DC AL1(7),CL10'MAXRECS',C'D',AL2(AMAXREC-ANC),AL2(0)
DC AL1(8),CL10'LOCKFILE',C'S',AL2(ALOCKL-ANC),AL2(255)
DC AL1(0)
* DCBS (RMODE 24)
PRTDCB DCB DDNAME=SYSPRINT,DSORG=PS,MACRF=PM,RECFM=VB,LRECL=259, X
BLKSIZE=3120
CFGDCB DCB DDNAME=SMFRCFG,DSORG=PS,MACRF=GM,EODAD=CFGEOF
LTORG
*
BUF LOCTR
DS 0D
F4SA DS 64D SAVE AREA FOR THE AMODE 64 CALLS
MSGBUF DS CL(MSGMAX+16)
DS 0D
DECBUF DS CL24
LOGREC DS CL260
CFGREC DS CL256
HOLDBUF DS CL256
PIPEBUF DS CL64
DS 0D
CHDR DS XL20
DS 0D
IOV DS (IOVMAX)XL8
DS 0D
RBUF DS CL(RBUFSZ)
*
***********************************************************************
* ANCHOR - SHARED BY THE THREE TASKS *
***********************************************************************
ANC DSECT
ASTOP DS X 1 = STOP REQUESTED
ASMFCON DS X 1 = CONNECTED TO THE RESOURCE
ACOLLCON DS X 1 = CONNECTED TO THE COLLECTOR
ATRACE DS X 1 = TRACE ON
DS 0D
AQHEAD DS D LAST COMMITTED (GETTER)
AQSENT DS D LAST SENT (SENDER)
AQTAIL DS D LAST ACKED (SENDER)
AWAITING DS F 1 = SENDER IDLE IN POLL
APRTDCB DS A SYSPRINT DCB (MAIN COPY)
ARING DS A
ADICTA DS A
ADICTN DS F
ADICTX DS F
ADICT DS (MAXDICT)XL16 APPLID(8) LEN(4) DATA@(4)
AWAKER DS F PIPE READ END
AWAKEW DS F PIPE WRITE END
ALOCKFD DS F
ASTOPECB DS F
AGETECB DS F
ASNDECB DS F
AGETTCB DS A
ASNDTCB DS A
ATOKEN DS XL16
DS 0D
SGETS DS D STATISTICS
SSUB1 DS D
SOTHER DS D
SDICTS DS D
SPERF DS D
SMISSED DS D
SDROP DS D
SSENTR DS D
SSENTB DS D
SCONNECT DS D
SSMFCON DS D
SBATCHES DS D
SWAKES DS D
AMAXREC DS D CONFIGURATION
AHOSTIP DS F
APORT DS F
ASLOTS DS F
AWINDOW DS F
ABATCH DS F
ARETRY DS F
AHBEAT DS F
AACKTO DS F
ADRAIN DS F
ASTATINT DS F
ASTATSND DS F
ARESL DS H
ARES DS CL26
AHOSTL DS H
AHOST DS CL64
ALOCKL DS H
ALOCK DS CL256
ASYSN DS CL8 IDENTITY
AJOBN DS CL8
AJOBID DS CL8
ASTARTT DS CL19
DS 0D
AINST DS D
ASTARTUS DS D
ANCLEN EQU *-ANC
*
COM DSECT
IEZCOM
CIB DSECT
IEZCIB
DCBD DSORG=PS,DEVD=DA
END SMFREAL